Gecko [ theprintave.ca ]

Name	Size	Permission	Date
file	[ DIR ]	drwxr-xr-x	2024-03-13 02:55
urn	[ DIR ]	drwxr-xr-x	2024-03-13 02:55
Escape.pm	6.9 KB	-rw-r--r--	2021-10-25 20:58
Heuristic.pm	6.37 KB	-rw-r--r--	2021-10-25 20:58
IRI.pm	794 B	-rw-r--r--	2021-10-25 20:58
QueryParam.pm	4.75 KB	-rw-r--r--	2021-10-25 20:58
Split.pm	2.3 KB	-rw-r--r--	2021-10-25 20:58
URL.pm	5.36 KB	-rw-r--r--	2021-10-25 20:58
WithBase.pm	3.77 KB	-rw-r--r--	2021-10-25 20:58
_foreign.pm	107 B	-rw-r--r--	2021-10-25 20:58
_generic.pm	5.69 KB	-rw-r--r--	2021-10-25 20:58
_idna.pm	2.03 KB	-rw-r--r--	2021-10-25 20:58
_ldap.pm	3.17 KB	-rw-r--r--	2021-10-25 20:58
_login.pm	231 B	-rw-r--r--	2021-10-25 20:58
_punycode.pm	5.49 KB	-rw-r--r--	2021-10-25 20:58
_query.pm	2.47 KB	-rw-r--r--	2021-10-25 20:58
_segment.pm	416 B	-rw-r--r--	2021-10-25 20:58
_server.pm	3.64 KB	-rw-r--r--	2021-10-25 20:58
_userpass.pm	1.01 KB	-rw-r--r--	2021-10-25 20:58
data.pm	3.31 KB	-rw-r--r--	2021-10-25 20:58
file.pm	9.53 KB	-rw-r--r--	2021-10-25 20:58
ftp.pm	1.03 KB	-rw-r--r--	2021-10-25 20:58
gopher.pm	2.37 KB	-rw-r--r--	2021-10-25 20:58
http.pm	425 B	-rw-r--r--	2021-10-25 20:58
https.pm	144 B	-rw-r--r--	2021-10-25 20:58
ldap.pm	2.86 KB	-rw-r--r--	2021-10-25 20:58
ldapi.pm	440 B	-rw-r--r--	2021-10-25 20:58
ldaps.pm	144 B	-rw-r--r--	2021-10-25 20:58
mailto.pm	1.62 KB	-rw-r--r--	2021-10-25 20:58
mms.pm	125 B	-rw-r--r--	2021-10-25 20:58
news.pm	1.42 KB	-rw-r--r--	2021-10-25 20:58
nntp.pm	127 B	-rw-r--r--	2021-10-25 20:58
nntps.pm	144 B	-rw-r--r--	2021-10-25 20:58
pop.pm	1.18 KB	-rw-r--r--	2021-10-25 20:58
rlogin.pm	129 B	-rw-r--r--	2021-10-25 20:58
rsync.pm	207 B	-rw-r--r--	2021-10-25 20:58
rtsp.pm	125 B	-rw-r--r--	2021-10-25 20:58
rtspu.pm	126 B	-rw-r--r--	2021-10-25 20:58
sftp.pm	98 B	-rw-r--r--	2021-10-25 20:58
sip.pm	1.66 KB	-rw-r--r--	2021-10-25 20:58
sips.pm	143 B	-rw-r--r--	2021-10-25 20:58
snews.pm	172 B	-rw-r--r--	2021-10-25 20:58
ssh.pm	175 B	-rw-r--r--	2021-10-25 20:58
telnet.pm	128 B	-rw-r--r--	2021-10-25 20:58
tn3270.pm	128 B	-rw-r--r--	2021-10-25 20:58
urn.pm	2.12 KB	-rw-r--r--	2021-10-25 20:58

Rename

package URI::Split;

use strict;
use warnings;

our $VERSION = '5.10';

use Exporter 5.57 'import';
our @EXPORT_OK = qw(uri_split uri_join);

use URI::Escape ();

sub uri_split {
     return $_[0] =~ m,(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:\?([^#]*))?(?:#(.*))?,;
}

sub uri_join {
    my($scheme, $auth, $path, $query, $frag) = @_;
    my $uri = defined($scheme) ? "$scheme:" : "";
    $path = "" unless defined $path;
    if (defined $auth) {
	$auth =~ s,([/?\#]), URI::Escape::escape_char($1),eg;
	$uri .= "//$auth";
	$path = "/$path" if length($path) && $path !~ m,^/,;
    }
    elsif ($path =~ m,^//,) {
	$uri .= "//";  # XXX force empty auth
    }
    unless (length $uri) {
	$path =~ s,(:), URI::Escape::escape_char($1),e while $path =~ m,^[^:/?\#]+:,;
    }
    $path =~ s,([?\#]), URI::Escape::escape_char($1),eg;
    $uri .= $path;
    if (defined $query) {
	$query =~ s,(\#), URI::Escape::escape_char($1),eg;
	$uri .= "?$query";
    }
    $uri .= "#$frag" if defined $frag;
    $uri;
}

__END__

=head1 NAME

URI::Split - Parse and compose URI strings

=head1 SYNOPSIS

use URI::Split qw(uri_split uri_join);
 ($scheme, $auth, $path, $query, $frag) = uri_split($uri);
 $uri = uri_join($scheme, $auth, $path, $query, $frag);

=head1 DESCRIPTION

Provides functions to parse and compose URI
strings.  The following functions are provided:

=over

=item ($scheme, $auth, $path, $query, $frag) = uri_split($uri)

Breaks up a URI string into its component
parts.  An C<undef> value is returned for those parts that are not
present.  The $path part is always present (but can be the empty
string) and is thus never returned as C<undef>.

No sensible value is returned if this function is called in a scalar
context.

=item $uri = uri_join($scheme, $auth, $path, $query, $frag)

Puts together a URI string from its parts.
Missing parts are signaled by passing C<undef> for the corresponding
argument.

Minimal escaping is applied to parts that contain reserved chars
that would confuse a parser.  For instance, any occurrence of '?' or '#'
in $path is always escaped, as it would otherwise be parsed back
as a query or fragment.

=back

=head1 SEE ALSO

L<URI>, L<URI::Escape>

=head1 COPYRIGHT

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut