Gecko [ theprintave.ca ]

Name	Size	Permission	Date
alarm.awk	2.31 KB	-rw-r--r--	2020-04-14 11:44
anagram.awk	1.33 KB	-rw-r--r--	2020-04-14 11:44
awksed.awk	515 B	-rw-r--r--	2020-04-14 11:44
cut.awk	3.61 KB	-rw-r--r--	2020-04-14 11:44
dupword.awk	507 B	-rw-r--r--	2020-04-14 11:44
egrep.awk	1.91 KB	-rw-r--r--	2020-04-14 11:44
extract.awk	1.84 KB	-rw-r--r--	2020-04-14 11:44
guide.awk	165 B	-rw-r--r--	2020-04-14 11:44
histsort.awk	283 B	-rw-r--r--	2020-04-14 11:44
id.awk	1.22 KB	-rw-r--r--	2020-04-14 11:44
igawk.sh	3.11 KB	-rw-r--r--	2020-04-14 11:44
indirectcall.awk	1.91 KB	-rw-r--r--	2020-04-14 11:44
labels.awk	1014 B	-rw-r--r--	2020-04-14 11:44
pi.awk	341 B	-rw-r--r--	2020-04-14 11:44
split.awk	1.17 KB	-rw-r--r--	2020-04-14 11:44
tee.awk	770 B	-rw-r--r--	2020-04-14 11:44
testbits.awk	736 B	-rw-r--r--	2020-04-14 11:44
translate.awk	1.15 KB	-rw-r--r--	2020-04-14 11:44
uniq.awk	2.64 KB	-rw-r--r--	2020-04-14 11:44
wc.awk	1.45 KB	-rw-r--r--	2020-04-14 11:44
wordfreq.awk	347 B	-rw-r--r--	2020-04-14 11:44

Rename

# uniq.awk --- do uniq in awk
#
# Requires getopt() and join() library functions
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993

function usage()
{
    print("Usage: uniq [-udc [-n]] [+n] [ in [ out ]]") > "/dev/stderr"
    exit 1
}

# -c    count lines. overrides -d and -u
# -d    only repeated lines
# -u    only nonrepeated lines
# -n    skip n fields
# +n    skip n characters, skip fields first

BEGIN {
    count = 1
    outputfile = "/dev/stdout"
    opts = "udc0:1:2:3:4:5:6:7:8:9:"
    while ((c = getopt(ARGC, ARGV, opts)) != -1) {
        if (c == "u")
            non_repeated_only++
        else if (c == "d")
            repeated_only++
        else if (c == "c")
            do_count++
        else if (index("0123456789", c) != 0) {
            # getopt() requires args to options
            # this messes us up for things like -5
            if (Optarg ~ /^[[:digit:]]+$/)
                fcount = (c Optarg) + 0
            else {
                fcount = c + 0
                Optind--
            }
        } else
            usage()
    }

if (ARGV[Optind] ~ /^\+[[:digit:]]+$/) {
        charcount = substr(ARGV[Optind], 2) + 0
        Optind++
    }

for (i = 1; i < Optind; i++)
        ARGV[i] = ""

if (repeated_only == 0 && non_repeated_only == 0)
        repeated_only = non_repeated_only = 1

if (ARGC - Optind == 2) {
        outputfile = ARGV[ARGC - 1]
        ARGV[ARGC - 1] = ""
    }
}
function are_equal(    n, m, clast, cline, alast, aline)
{
    if (fcount == 0 && charcount == 0)
        return (last == $0)

if (fcount > 0) {
        n = split(last, alast)
        m = split($0, aline)
        clast = join(alast, fcount+1, n)
        cline = join(aline, fcount+1, m)
    } else {
        clast = last
        cline = $0
    }
    if (charcount) {
        clast = substr(clast, charcount + 1)
        cline = substr(cline, charcount + 1)
    }

return (clast == cline)
}
NR == 1 {
    last = $0
    next
}

{
    equal = are_equal()

if (do_count) {    # overrides -d and -u
        if (equal)
            count++
        else {
            printf("%4d %s\n", count, last) > outputfile
            last = $0
            count = 1    # reset
        }
        next
    }

if (equal)
        count++
    else {
        if ((repeated_only && count > 1) ||
            (non_repeated_only && count == 1))
                print last > outputfile
        last = $0
        count = 1
    }
}

END {
    if (do_count)
        printf("%4d %s\n", count, last) > outputfile
    else if ((repeated_only && count > 1) ||
            (non_repeated_only && count == 1))
        print last > outputfile
    close(outputfile)
}